bump version to 3.00.00_1; update POD a bit; include contact info for myself; declare this module deprecated and in maintenance mode; include Module::Build in the 'inc' dir to avoid a warning about it being deprecated from core inclusion; add mention of the UNIVERSAL->isa() bug created by Class::Std::Fast to the POD for BUGS AND LIMITATIONS.

2014-08-27 17:39:52 -04:00
parent 2624a9d5c0
commit 7d81cfce87
137 changed files with 21743 additions and 165 deletions
@@ -0,0 +1,65 @@
+package Module::Build::PodParser;
+
+use strict;
+use vars qw($VERSION);
+$VERSION = '0.4206';
+$VERSION = eval $VERSION;
+use vars qw(@ISA);
+
+sub new {
+  # Perl is so fun.
+  my $package = shift;
+
+  my $self;
+  @ISA = ();
+  $self = bless {have_pod_parser => 0, @_}, $package;
+
+  unless ($self->{fh}) {
+    die "No 'file' or 'fh' parameter given" unless $self->{file};
+    open($self->{fh}, '<', $self->{file}) or die "Couldn't open $self->{file}: $!";
+  }
+
+  return $self;
+}
+
+sub parse_from_filehandle {
+  my ($self, $fh) = @_;
+
+  local $_;
+  while (<$fh>) {
+    next unless /^=(?!cut)/ .. /^=cut/;  # in POD
+    # Accept Name - abstract or C<Name> - abstract
+    last if ($self->{abstract}) = /^ (?: [a-z_0-9:]+ | [BCIF] < [a-z_0-9:]+ > ) \s+ - \s+ (.*\S) /ix;
+  }
+
+  my @author;
+  while (<$fh>) {
+    next unless /^=head1\s+AUTHORS?/i ... /^=/;
+    next if /^=/;
+    push @author, $_ if /\@/;
+  }
+  return unless @author;
+  s/^\s+|\s+$//g foreach @author;
+
+  $self->{author} = \@author;
+
+  return;
+}
+
+sub get_abstract {
+  my $self = shift;
+  return $self->{abstract} if defined $self->{abstract};
+
+  $self->parse_from_filehandle($self->{fh});
+
+  return $self->{abstract};
+}
+
+sub get_author {
+  my $self = shift;
+  return $self->{author} if defined $self->{author};
+
+  $self->parse_from_filehandle($self->{fh});
+
+  return $self->{author} || [];
+}